	SUBROUTINE DANNO (DATE0, DATE, OMEG0, ANGI0, OMEG, ANGI, ANGN,
	1 ANGJ, POMEG,  DOM)
C
C ANNO2 est un sous-programme de calcul de precession (anciennes formules
C FK4) des elements orbitaux, applicable au plan des anneaux de Saturne.
C En entree : *DATE0 et DATE, les dates juliennes initiales et finales,
C           : *OMEG0 et ANGI0, la longitude du noeud ascendant du plan des
C anneaux sur l'ecliptique et l'inclinaison correspondante a la date DATE0
C en DEGRADians.
C En sortie : *OMEG et ANGI apres la correction de precession a la date DATE,
C           : *ANGN et ANGJ, valeurs en DEGRADians des angles N et J, longitude
C du noeud ascendant du plan des anneaux sur l'equateur terrestre et
C l'inclinaison correspondante a la date DATE,
C           : *POMEG, valeur en DEGRADian de l'arc de cercle appartenant au plan
C des anneaux, entre le noeud sur l'equateur terrestre et le noeud sur
C l'ecliptique a la date DATE,
C           : *DOM = POMEG-OMEG
C
	IMPLICIT REAL*8 (A-H, O-Z)
	COMMON/BLKPI/PI, DPI, DEGRAD, RADEG
	COMMON/BLKDAT/DATE50,DATE2000,ANJBES
C
	T0 = (DATE0-DATE50)/ANJBES+1950.
	T = (DATE-DATE50)/ANJBES+1950.
	PT = (T-T0)/1000.
	GT = (T0-1900.)/1000.
	PT2 = PT*PT
	PT3 = PT2*PT
	GT2 = GT*GT
	GT3 = GT2*GT
	A = (32869.*GT+56.*GT2)/3600.
	B = (-8694.-55.*GT)/3600.
	FI = (173.955+A+B*PT+PT2/1200.)*DEGRAD
	ANK = (471.07-6.75*GT+0.57*GT2)*PT+(-3.37+0.57*GT)*PT2+0.05*PT3
	ANK = (ANK/3600.)*DEGRAD
	OLAND = (50256.41+222.29*GT+0.26*GT2)*PT
	1 +(111.15+0.26*GT)*PT2+0.10*PT3
	OLAND = (OLAND/3600.)*DEGRAD
	EPS = ((OBLI(T))/3600.)*DEGRAD
	FFI = FI-OMEG0
	ANIO = ANGI0
C
	S1 = COS(ANIO)*COS(ANK)+SIN(ANIO)*SIN(ANK)*COS(FFI)
	S2 = SIN(ANIO)*SIN(FFI)
	S3 = -SIN(ANK)*COS(ANIO)+COS(ANK)*SIN(ANIO)*COS(FFI)
	PX1 = ATAN2(S2,S3)
	OMEG = OLAND+FI-PX1
	OMEG = DMOD(OMEG, DPI)
	IF (OMEG.LT.0) OMEG = OMEG+DPI
	ANGI = ATAN2(S2/SIN(PX1), S1)
C
	Z1 = SIN(ANGI)*SIN(OMEG)
	Z2 = COS(ANGI)*SIN(EPS)+SIN(ANGI)*DCOS(EPS)*COS(OMEG)
	Z3 = COS(ANGI)*COS(EPS)-SIN(ANGI)*SIN(EPS)*COS(OMEG)
C
	ANGN = ATAN2(Z1, Z2)
	ANGN = DMOD(ANGN, DPI)
	IF (ANGN.LT.0) ANGN = ANGN+DPI
	ANGJ = ATAN2(Z2/COS(ANGN), Z3)
	POMEG = ASIN((SIN(EPS)*SIN(OMEG))/SIN(ANGJ))
	DOM = POMEG-OMEG
	RETURN
	END
