	SUBROUTINE DIONE(DAY,I,R)

C	SOUS PROGRAMME DE CALCUL DES COORDONNEES DIFFERENTIELLES 
C	RECTILIGNES EQUATORIALES B1950.0 DE MIMAS PAR RAPPORT A
C	LA PLANETE SATURNE
C	EN ENTREE :
C	*    DAY= DATE JULIENNE OBSERVATION EN JOUR FRACTIONNAIRE
C	*      I= INDICE DE LA THEORIE DU MOUVEMENT DU SATELLITE
C	ADOPTEE POUR CHAQUE ELEMENT ORBITAL ET PETITE VARIATION
C	        =1 G.STRUVE(1930)
C	        =2 Y.KOZAI (1957)
C	        =3 M.RAPAPORT(1977)PLANS DATE
C	        =4 I.G.CHUGUNOV (1984)
C	        =5 H.A.GARCIA (1972)
C	        =6 A.T.SINCLAIR (1977)
C	        =7 G.DOURNEAU (1987)
C	EN SORTIE :
C	*   R (K) = COORDONNEES RECTILIGNES EQUATORIALES B1950.0 
C	R(K=1,3)=DX,XY,DZ PAR RAPPORT A LA PLANETE SATURNE EN U.A. 

C	TRANSMISSIONS PAR COMMON A ETIQUETTE

C	*  COMMON/BLKDIVAL : ELEMENTS ORBITAUX DE DIONE

	IMPLICIT REAL*8(A-H,O-Z)
	CHARACTER*8 NOMSAT(8),NOM(8,24)
	DIMENSION EL(8,24),E0(8),AN(8),TETA0(8),GPI0(8),
	1EX(8),AI(8),AA(8),TETAV(8),GPIV(8),A1(8),
	1B1C(8),B1V(8),A2(8),B2C(8),B2V(8),R(3),
	1OMEG50C(8),ANGI50C(8),OMEG50V(8),ANGI50V(8),XDE(8),ACL(8)

	COMMON/BLKPI/PI,DPI,DEGRAD,RADEG
	COMMON/BLKDAT/DATE50,DATE2000,ANJBES
	COMMON/BLKDIVAL/E0,AN,TETA0,GPI0,EX,AI,AA,TETAV,GPIV,
	1 OMEG50C,ANGI50C,OMEG50V,ANGI50V,	
	2 XDE,B1C,B1V,ACL,B2C,B2V	!  XDE RAPPORT DES LIBRATIONS DIONE-ENCELADE
	COMMON/BLKENVAL/EL2(8,24)

	EQUIVALENCE (EL(1,1),E0(1))

	DATA DS/9.538937D0/
	  	
C	FIN DES DATA

	DT50=(DAY-DATE50)/36525.
	DJ=DAY-2411093.
	T=DT50*100.+1950.
	DT=DJ/365.25

	IF((I-2)*(I-3)*(I-7).EQ.0)THEN
	B1C(I)=EL2(I,15)
	B1V(I)=EL2(I,16)	
	B2C(I)=EL2(I,18)
	B2V(I)=EL2(I,19)
	EL(8,15)=EL2(8,15)
	EL(8,16)=EL2(8,16)
	EL(8,18)=EL2(8,18)
	EL(8,19)=EL2(8,19)
	ELSE IF(I.EQ.5)THEN
	A1(I)=-1.285
	A2(I)= 0.206
	ELSE IF (I.EQ.6)THEN
	A1(I)=-0.88
	A2(I)=-0.75
	ELSE IF(I.EQ.1)THEN
	A1(I)=-0.93
	A2(I)=-0.91
	ELSE IF(I.EQ.4)THEN
	A1(I)=-0.81
	A2(I)=-0.66
	END IF

	OMEG50=(OMEG50C(I)+OMEG50V(I)*DT50)*DEGRAD
	ANGI50=(ANGI50C(I)+ANGI50V(I)*DT50)*DEGRAD
	CALL DANNO(DATE50,DATE50,OMEG50,ANGI50,
	1OMEG0,ANGI0,ANGN0,ANGJ0,POMEG0,DOM0)
	IF((I-2)*(I-3)*(I-7).EQ.0)THEN
	A1(I)=XDE(I)*EL2(I,14)
	A2(I)=XDE(I)*EL2(I,17)
	END IF
	ARG1=B1C(I)+B1V(I)*DT
	ARG1=(DMOD(ARG1,360.D0))*DEGRAD
	ARG2=B2V(I)*DT+B2C(I)
	ARG2=(DMOD(ARG2,360.D0))*DEGRAD

C	Acceleration seculaire en longitude
	
	AL1=E0(I)+AN(I)*DJ + ACL(I)*(DT/100.)*(DT/100.)
	1+(A1(I)*SIN(ARG1)+A2(I)*SIN(ARG2))/60.
	AL1=(DMOD(AL1,360.D0))*DEGRAD
	GPI=GPI0(I)+GPIV(I)*DT
	GPI=(DMOD(GPI,360.D0))*DEGRAD
	ANOM=AL1-GPI
	GPI=GPI+DOM0
	TETA=TETA0(I)+TETAV(I)*DT
	TETA=(DMOD(TETA,360.D0))*DEGRAD+DOM0
	GPI=GPI-TETA
	AIR=AI(I)*DEGRAD
	EAA=AA(I)*DS*DEGRAD/3600.D0
	CALL EECR(EAA,EX(I),AIR,TETA,GPI,ANOM,R)
	CALL ROTA(R,0.D0,-ANGJ0,-ANGN0)
	RETURN
	END
