	SUBROUTINE ECOREQAN(SOMEG,SI,SGPI,OMEG0,ANGI0,POMEG0,
	1TETA,AI,PIR)
C
C	SOUS PROGRAMME DE CALCUL DE LA LONGITUDE DU NOEUD 
C	ASCENDANT DE L'ORBITE D'UN SATELLITE A PARTIR DU NOEUD
C	ASCENDANT DU PLAN DES ANNEAUX SUR L'EQUATEUR TERRESTRE
C	SUR LE PLAN DES ANNEAUX (TETA),DE SON INCLINAISON (AI)
C	SUR CE MEME PLAN ET DE LA LONGITUDE DU PERISATURNE(PIR)
C	MESURE COMME TETA 
C	EN PARTANT DE LA LONGITUDE DU NOEUD(SJ)ET DU PERISATURNE(SGPI)
C	A PARTIR DE L'EQUINOXE SUR L'ECLIPTIQUE JUSQU'AU NOEUD
C	ASCENDANT DE L'ORBITE ET DE L'INCLINAISON SUR L'ECLIPTIQUE
C	(SI) ET DES ANGLES RELATIFS AU PLAN DES ANNEAUX(OMEG0)
C	A PARTIR DE L'EQUINOXE SUR L'ECLIPTIQUE JUSQU'AU NOEUD
C	ASCENDANT DU PLAN DES ANNEAUX (ANGI0),L'INCLINAISON
C	DU PLAN DES ANNEAUX SUR L'ECLIPTIQUE ET (POMEG0)
C	LA PORTION D'ARC D'ANNEAU SITUE ENTRE L'EQUATEUR TERRESTRE
C	ET 'ECLIPTIQUE
C
	IMPLICIT REAL*8(A-H,O-Z)
	COMMON/BLKPI/PI,DPI,DEGRAD,RADEG
	SJ=SOMEG-OMEG0
	Z1=SIN(SI)*SIN(SJ)
	Z2=-COS(SI)*SIN(ANGI0)+SIN(SI)*COS(ANGI0)*COS(SJ)
	Z3=COS(SI)*COS(ANGI0)+SIN(SI)*SIN(ANGI0)*COS(SJ)
	DTPOM=DATAN2(Z1,Z2)
	TETA=DMOD((DTPOM+POMEG0),DPI)
	IF(TETA.LT.0)TETA=TETA+DPI
	AI=DATAN2((Z2/COS(DTPOM)),Z3)
	AI=DMOD(AI,DPI)
	P1=SIN(ANGI0)*SIN(SJ)
	P2=SIN(SI)*COS(ANGI0)-COS(SI)*SIN(ANGI0)*COS(SJ)
	PSIP=DATAN2(P1,P2)
	PIR=SGPI-SOMEG-PSIP
	IF(PIR.LT.0)PIR=PIR+DPI
	RETURN
	END

