	SUBROUTINE EECR(A, E, I, G, P, L, R)
C
	IMPLICIT REAL *8 (A-H, O-Z)
	REAL *8 I, L, M, N
	DIMENSION R(3)
C
C Calcul des coordonnees rectangulaires R(3) a partir des elements :
C G = Omega, P = Longitude periastre
C
	GE = EKEPLR(L, E)
	W = DCOS(GE)
	U = W-E
	V = DSIN(GE)
C
	CG = DCOS(G)
	SG = DSIN(G)
	CP = DCOS(P)
	SP = DSIN(P)
	CI = DCOS(I)
	SI = DSIN(I)
	CGCP = CG*CP
	SGSP = SG*SP
	CGSP = CG*SP
	SGCP = SG*CP
C
	PX = CGCP-CI*SGSP
	PY = SGCP+CI*CGSP
	PZ = SI*SP
	QX = -CGSP-CI*SGCP
	QY = -SGSP+CI*CGCP
	QZ = SI*CP
C
	F = A*DSQRT(1.D0-E**2)
	AX = A*PX
	AY = A*PY
	AZ = A*PZ
	BX = F*QX
	BY = F*QY
 	BZ = F*QZ
C
	R(1) = AX*U+BX*V
	R(2) = AY*U+BY*V
	R(3) = AZ*U+BZ*V
C
	RETURN
	END
