	SUBROUTINE ENCELADE(DAY,I,R)

C	SOUS PROGRAMME DE CALCUL DES COORDONNEES DIFFERENTIELLES 
C	RECTILIGNES EQUATORIALES B1950.0 DE MIMAS PAR RAPPORT A
C	LA PLANETE SATURNE
C	EN ENTREE :
C	*    DAY= DATE JULIENNE OBSERVATION EN JOUR FRACTIONNAIRE
C	*      I= INDICE DE LA THEORIE DU MOUVEMENT DU SATELLITE
C	ADOPTEE POUR CHAQUE ELEMENT ORBITAL ET PETITE VARIATION
C	        =1 G.STRUVE (1930)
C	        =2 Y.KOZAI (1957)
C	        =3 M.RAPAPORT(1977)PLANS DATE
C	        =4 I.G.CHUGUNOV (1984)
C	        =5 (Ne pas utiliser)
C	        =6 (Ne pas utiliser)
C	        =7 G.DOURNEAU (1987)
C	EN SORTIE :
C	*   R (K) = COORDONNEES RECTILIGNES EQUATORIALES B1950.0 
C	R(K=1,3)=DX,XY,DZ PAR RAPPORT A LA PLANETE SATURNE EN U.A. 

C	TRANSMISSIONS PAR COMMON A ETIQUETTE
C	*  COMMON/BLKENVAL :	VALEURS DES ELEMENTS ORBITAUX

	IMPLICIT REAL*8(A-H,O-Z)
	CHARACTER*8 NOMSAT(8),NOM(8,24)
	DIMENSION EL(8,24),E0(8),AN(8),TETA0(8),GPI0(8),
	1 EX(8),AI(8),AA(8),TETAV(8),GPIV(8),A1(8),
	1 B1C(8),B1V(8),A2(8),B2C(8),B2V(8),R(3),
	1 OMEG50C(8),ANGI50C(8),OMEG50V(8),ANGI50V(8),
	1 EP2(8),EP4(8),COEFEP2(8)

	COMMON/BLKPI/PI,DPI,DEGRAD,RADEG
	COMMON/BLKDAT/DATE50,DATE2000,ANJBES
	COMMON/BLKENVAL/E0,AN,TETA0,GPI0,EX,AI,AA,TETAV,GPIV,
	1 OMEG50C,ANGI50C,OMEG50V,ANGI50V,
	2 A1,B1C,B1V,A2,B2C,B2V	
	COMMON/BLKDIVAL/EL4(8,24)

	EQUIVALENCE (EL(1,1),E0(1))

	DATA DS/9.538937D0/
	IF((I-7)*(I-3).EQ.0)THEN
C	Fixation du perisaturne force
	GPI0(I)=2.*EL4(I,1)-E0(I)
	GPIV(I)=(2.*EL4(I,2)-AN(I))*365.25
C	Non fixation de la precession du noeud 
C	TETAV(I)=-152.7D0
C	TETAV(I)=-((2.*EL4(I,2)-AN(I))*365.25+B1V(I)-3.28)	
C	TETAV(I)= -(2.*EL4(I,2)-AN(I))*365.25+B1V(I)	
C	Fixation de la pulsation et de la phase de la 2eme libration
	B2C(I) =  2*EL4(I,1)-E0(I)        -EL4(I,4)
	B2V(I) = (2*EL4(I,2)-AN(I))*365.25-EL4(I,9)
	END IF
	
C	Calcul des coefficients de A2 lie a A1,B1V et B2V (Kozai,1976)
	EP4(I) = EL4(I,5)	!	EXC.PROPRE DE DIONE
	COEFEP2(I)=3*EX(I)*AN(I)*365.25
C	COEFEP2(I)=3*AN(I)*365.25
	R7S5=0.360366339D0	!	a(70)1/a(50)2	Le Verrier
	  	
C	FIN DES DATA

	DT50=(DAY-DATE50)/36525.
	DJ=DAY-2411093.
	T=DT50*100.+1950.
	DT=DJ/365.25
	IT=1
1	OMEG50=(OMEG50C(I)+OMEG50V(I)*DT50)*DEGRAD
	ANGI50=(ANGI50C(I)+ANGI50V(I)*DT50)*DEGRAD
	CALL DANNO(DATE50,DATE50,OMEG50,ANGI50,
	1OMEG0,ANGI0,ANGN0,ANGJ0,POMEG0,DOM0)
C	A2 est lie par la theorie a A1,B1V et B2V
	EP2(I) = A1(I)*DEGRAD*B1V(I)/(COEFEP2(I)*60.)!EXC.PR.D'ENCELADE
	A2(I)=A1(I)*R7S5*(EP4(I)/EP2(I))*(B1V(I)*(B1V(I)-3.28))
	1 /(B2V(I)*B2V(I))
	ARG1=B1C(I)+B1V(I)*DT
	ARG1=(DMOD(ARG1,360.D0))*DEGRAD
	ARG2=B2V(I)*DT+B2C(I)
	ARG2=(DMOD(ARG2,360.D0))*DEGRAD
	AL1=E0(I)+AN(I)*DJ
	1+(A1(I)*SIN(ARG1)+A2(I)*SIN(ARG2))/60.
	AL1=(DMOD(AL1,360.D0))*DEGRAD
	GPI=GPI0(I)+GPIV(I)*DT
	GPI=(DMOD(GPI,360.D0))*DEGRAD
	ANOM=AL1-GPI
	GPI=GPI+DOM0
	TETA=TETA0(I)+TETAV(I)*DT
	TETA=(DMOD(TETA,360.D0))*DEGRAD+DOM0
	GPI=GPI-TETA
	AIR=AI(I)*DEGRAD
	EAA=AA(I)*DS*DEGRAD/3600.D0
	CALL EECR(EAA,EX(I),AIR,TETA,GPI,ANOM,R)
	CALL ROTA(R,0.D0,-ANGJ0,-ANGN0)
	RETURN
	END


