	SUBROUTINE MIMAS(DAY,I,R)

C	SOUS PROGRAMME DE CALCUL DES COORDONNEES DIFFERENTIELLES 
C	RECTILIGNES EQUATORIALES B1950.0 DE MIMAS PAR RAPPORT A
C	LA PLANETE SATURNE
C	EN ENTREE :
C	*    DAY= DATE JULIENNE OBSERVATION EN JOUR FRACTIONNAIRE
C	*      I= INDICE DE LA THEORIE DU MOUVEMENT DU SATELLITE
C	ADOPTEE POUR CHAQUE ELEMENT ORBITAL ET PETITE VARIATION
C	        =1 G.STRUVE(1930)
C	        =2 Y.KOZAI (1957)
C	        =3 M.RAPAPORT(1977)PLANS DATE
C	        =4 I.G.CHUGUNOV (1984)
C	        =5 (Ne pas utiliser)
C	        =6 (Ne pas utiliser)
C	        =7 G.DOURNEAU (1987)
C	EN SORTIE :
C	*   R (K) = COORDONNEES RECTILIGNES EQUATORIALES B1950.0 
C	R(K=1,3)=DX,XY,DZ PAR RAPPORT A LA PLANETE SATURNE EN U.A. 

C	TRANSMISSIONS PAR COMMON A ETIQUETTE

C	*  COMMON/BLKMIVAL :	VALEURS DES ELEMENTS ORBITAUX

	IMPLICIT REAL*8(A-H,O-Z)
	DIMENSION EL(8,24),E0(8),AN(8),TETA0(8),GPI0(8),
	1 EX(8),AI(8),AA(8),TETAV(8),GPIV(8),S(8),A11(8),
	1 B1C(8),B1V(8),A2(8),B2C(8),B2V(8),A13(8),A15(8),
	1 R(3),OMEG50C(8),ANGI50C(8),OMEG50V(8),ANGI50V(8),
	1 XTM(8),ACT(8),ACP(8)

	COMMON/BLKPI/PI,DPI,DEGRAD,RADEG
	COMMON/BLKDAT/DATE50,DATE2000,ANJBES
	COMMON/BLKMIVAL/E0,AN,TETA0,GPI0,EX,AI,AA,TETAV,GPIV,
	1 OMEG50C,ANGI50C,OMEG50V,ANGI50V,
	2 A11,B1C,B1V,ACT,ACP,S
	COMMON/BLKTEVAL/EL3(8,24)

C	ACT Acceleration seculaire du noeud       
C	ACP      "           "     "  perisaturne 

	EQUIVALENCE (EL(1,1),E0(1))

	DATA DS/9.538937D0/
	DATA TMK/216.11D0/	!	Valeur obtenue a partir de Kozai

	XTM(I)=EL3(I,14)	!	transmettre par Tethys

C			!	TMK**2=A111**3/(3*A131*(1-XTM)**2)
C			!	XTM=a(Te)*m(Mi)/(a(Mi)*m(Te))=0.009959

C	FIN DES DATA

	DT50=(DAY-DATE50)/36525.
	DJ=DAY-2411093.
	T=DT50*100.+1950.
	DT=DJ/365.25
	IT=1
1	OMEG50=(OMEG50C(I)+OMEG50V(I)*DT50)*DEGRAD
	ANGI50=(ANGI50C(I)+ANGI50V(I)*DT50)*DEGRAD
	CALL DANNO(DATE50,DATE50,OMEG50,ANGI50,
	1 OMEG0,ANGI0,ANGN0,ANGJ0,POMEG0,DOM0)

C	FIXATION THEORIQUE DES ARGUMENTS DE LIBRATION (KOZAI,1957)

	A13(I) = (A11(I)**3)/(3*(TMK*TMK) * (1-XTM(I))*(1-XTM(I)))
	A15(I) = (A11(I)**5)/(5*(TMK**4)  * ((1-XTM(I))**4))

	ARG1=B1V(I)*(T-B1C(I))
	ARG1=(DMOD(ARG1,360.D0))*DEGRAD
	AL1=E0(I)+AN(I)*DJ+S(I)*(DT/100.)*(DT/100.)
	1+A11(I)*SIN(ARG1)+A13(I)*SIN(3.*ARG1)+A15(I)*SIN(5.*ARG1)
	IF(I.EQ.3)THEN
	AL1=AL1 - 0.143*SIN(1.5996*DT+23.495)*DEGRAD
	1 -0.069*SIN(1.5857*DT-93.883)*DEGRAD + 0.066*
	1 SIN(1.6134*DT+140.873)*DEGRAD
	END IF
	AL1=(DMOD(AL1,360.D0))*DEGRAD

C	ACCELERATION SECULAIRE DU PERISATURNE ACP(I)

	GPI=GPI0(I)+GPIV(I)*DT + ACP(I)*(DT/100.)*(DT/100.)
	GPI=(DMOD(GPI,360.D0))*DEGRAD
	ANOM=AL1-GPI
	GPI=GPI+DOM0 

C	ACCELERATION SECULAIRE DU NOEUD ACT(I) 

	TETA=TETA0(I)+TETAV(I)*DT + ACT(I)*(DT/100.)*(DT/100.)
	TETA=(DMOD(TETA,360.D0))*DEGRAD+DOM0
	GPI=GPI-TETA
	AIR=AI(I)*DEGRAD
	AAM=AA(I)*DS*DEGRAD/3600.D0
	CALL EECR(AAM,EX(I),AIR,TETA,GPI,ANOM,R)
	CALL ROTA(R,0.D0,-ANGJ0,-ANGN0)
	RETURN
	END


