	SUBROUTINE RHEA(DAY,I,R)
C	SOUS PROGRAMME DE CALCUL DES COORDONNEES DIFFERENTIELLES 
C	RECTILIGNES EQUATORIALES B1950.0 DE MIMAS PAR RAPPORT A
C	LA PLANETE SATURNE
C	EN ENTREE :
C	*    DAY= DATE JULIENNE OBSERVATION EN JOUR FRACTIONNAIRE
C	*      I= INDICE DE LA THEORIE DU MOUVEMENT DU SATELLITE
C	ADOPTEE POUR CHAQUE ELEMENT ORBITAL ET PETITE VARIATION
C	        =1 G.STRUVE(S1 A S6 ET S8)
C	        =2 Y.KOZAI (S1 A S6)
C	        =3 M.RAPAPORT(S1 A S6)PLANS DATE
C	        =4 I.G.CHUGUNOV (S1 A S6)
C	        =5 H.A.GARCIA(S3 A S6)
C	        =6 A.T.SINCLAIR (S3 A S6 ET S8),TAYLOR(S7)
C	        =7 G.DOURNEAU(S1 A S8)
C	EN SORTIE :
C	*   R (K) = COORDONNEES RECTILIGNES EQUATORIALES B1950.0 
C	R(K=1,3)=DX,XY,DZ PAR RAPPORT A LA PLANETE SATURNE EN U.A. 

C	TRANSMISSIONS PAR COMMON A ETIQUETTE

C	*  COMMON/BLKRHVAL : ELEMENTS ORBITAUX DE RHEA

	IMPLICIT REAL*8(A-H,O-Z)
	CHARACTER*8 NOMSAT(8),NOM(8,24)
	DIMENSION EL(8,24),E0(8),AN(8),TETA0(8),GPI0(8),
	1EX(8),AI(8),AA(8),TETAV(8),GPIV(8),RKOM(8),RKI(8),
	1R(3),OMEG50C(8),ANGI50C(8),OMEG50V(8),ANGI50V(8)

	COMMON/BLKPI/PI,DPI,DEGRAD,RADEG
	COMMON/BLKDAT/DATE50,DATE2000,ANJBES
	COMMON/BLKRHVAL/E0,AN,TETA0,GPI0,EX,AI,AA,TETAV,GPIV,
	1 OMEG50C,ANGI50C,OMEG50V,ANGI50V,RKOM,RKI
	COMMON/BLKTIVAL/EL6(8,24)

	EQUIVALENCE (EL(1,1),E0(1))

	DATA DS/9.538937D0/
	DATA TKR/0.0652D0/	!	Valeur de Garcia(1972)
	IF((I-7)*(I-3).EQ.0)GPIV(I)=-TETAV(I)!GPIV5 Fixe = - TETAV5 (Th:7)

C	Fixation de l'inclinaison du plan Laplacien sur le plan des anneaux (Sinclair,1977)

	IF (I.NE.1)THEN
	RKOM(I) = - 0.0078	
	RKI(I)  = - 0.0455
	ELSE 
	RKOM(I) = - 0.0135
	RKI(I)  = - 0.0465
	END IF

C	FIN DES DATA

	DT50=(DAY-DATE50)/36525.
	DJ=DAY-2411093.
	DJ1=DAY-2411368.
	DT=DJ/365.25
	DT1=DJ1/365.25
	OMEG50=(OMEG50C(I)+OMEG50V(I)*DT50)*DEGRAD
	ANGI50=(ANGI50C(I)+ANGI50V(I)*DT50)*DEGRAD
	CALL DANNO(DATE50,DATE50,OMEG50,ANGI50,
	1OMEG0,ANGI0,ANGN0,ANGJ0,POMEG0,DOM0)
	TETA=TETA0(I)+TETAV(I)*DT
	TETA=(DMOD(TETA,360.D0))*DEGRAD
	GPI=GPI0(I)+GPIV(I)*DT
	GPI=(DMOD(GPI,360.D0))*DEGRAD
	AI0=AI(I)*DEGRAD

	IF (I.NE.6)THEN
	TTETA = EL6(I,3) + EL6(I,8) * DT1
	ELSE
	TTETA = 44.5 - 0.5219 * DT1
	END IF

	TTETA=(DMOD(TTETA,360.D0))*DEGRAD
	IF (I.NE.6)THEN
	TGPI= EL6(I,4) + EL6(I,9) * DT1
	ELSE
	TGPI = 276.49 + 0.5219 * DT1
	END IF

	TGPI=(DMOD(TGPI,360.D0))*DEGRAD

	IF(I.EQ.2)THEN
	TS=(DAY-2415020.)/36525.
	SI = (2.4891+0.002435*TS)*DEGRAD
	SOM= (113.35-0.2597 * TS)*DEGRAD
	TAI0 = EL6(I,6) * DEGRAD
	TOM=OMEG0-0.1418*DEGRAD+SIN(TAI0)*SIN(TTETA)/SIN(ANGI0)
	G0=103.199*DEGRAD
	G=TGPI-TOM-4.6*DEGRAD
	DGPI=0.36833*(SIN(G+G)-SIN(G0+G0))
	G=G+DGPI*DEGRAD
	DGPI=0.36833*(SIN(G+G)-SIN(G0+G0))
	TGPI=TGPI+DGPI*DEGRAD
	END IF	!	I.EQ.2

	AL1=(E0(I)+AN(I)*DJ)*DEGRAD
	IF((I-6)*(I-7).EQ.0)THEN
	AL1 = AL1 + SIN(AI0)*TAN((RKI(I)*DEGRAD+ANGI0)/2.)*SIN(TETA)
	END IF
	AL1=DMOD(AL1,DPI)
	IF(AL1.LT.0)AL1=AL1+DPI

	IF((I-5)*(I-6)*(I-7).EQ.0)THEN
	P1=EX(I)*SIN(GPI)+0.001*SIN(TGPI)
	P2=EX(I)*COS(GPI)+0.001*COS(TGPI)
	PI1=DATAN2(P1,P2)
	IF(PI1.LT.0)PI1=PI1+DPI
	EX1=DABS(P2/COS(PI1))

	ELSE IF(I.EQ.1)THEN
	EX1=0.00098+EX(I)*COS(GPI)
	PI1=TGPI+17.64*DEGRAD*SIN(GPI)

	ELSE IF((I-2)*(I-3)*(I-4).EQ.0)THEN
	EX1=0.001+EX(I)*COS(GPI)
	PI1=TGPI+13.*DEGRAD*SIN(GPI)
	END IF	!	CALCULS DE EX ET PI

	RAA=AA(I)*DS*DEGRAD/3600.D0
	ANOM=AL1-PI1
	IF(ANOM.LT.0)ANOM=ANOM+DPI
	TKI = EL6(I,6) * TKR
	IF(I.EQ.1)TKI=0.016666
	IF(I.EQ.6)TKI=0.0201
	ROM=OMEG0+RKOM(I)*DEGRAD+((TKI*SIN(TTETA))*DEGRAD
	1+SIN(AI0)*SIN(TETA))/SIN(ANGI0)
	RI=ANGI0+RKI(I)*DEGRAD+SIN(AI0)*COS(TETA)
	1+(TKI*COS(TTETA))*DEGRAD

C	CALCUL DE TETA ET GAMA(AIR) A PARTIR DE OMEGA ET I(ANGI0)

	CALL ECOREQAN(ROM,RI,PI1,OMEG0,ANGI0,POMEG0,RTETA,AIR,PIR)
	CALL EECR(RAA,EX1,AIR,RTETA,PIR,ANOM,R)
	CALL ROTA(R,0.D0,-ANGJ0,-ANGN0)
	RETURN
	END
